Partenaire Microsoft

 

 

Bienvenue, Invité
Nom d'utilisateur : Mot de passe : Se souvenir de moi
  • Page :
  • 1

SUJET : Connecter un lecteur en fonction de l'ordinateur

Connecter un lecteur en fonction de l'ordinateur il y a 4 ans 9 mois #471

Voici un script qui permet de connecter un lecteur avec authentification en fonction du nom de l'ordinateur :
 
If ComputerNameBeginsWith("CDI") Then 
   ConnectDrive2 "X:","\\MyServer\MyShare","Description de ma ressource","utilisateur","motdepasse"
   End If
 
WScript.Quit   
 
'///////////////////////////////////////////////////////////
'// Check if the computer name begins with the given string
'// RDP is supported
Function ComputerNameBeginsWith(Name)
Dim Computer, RDP
Dim objNetwork, objShell
Set objNetwork=WScript.CreateObject("WScript.Network")
Set objShell=CreateObject("WScript.Shell") 
Computer=objShell.ExpandEnvironmentStrings("%CLIENTNAME%")
RDP=(Computer<>"" And Computer<>"%CLIENTNAME%" And Computer<>"Console")
If Not RDP Then 
   Computer=objNetwork.ComputerName 
   End If
ComputerNameBeginsWith=(InStr(Computer,Name)=1)
End Function
'///////////////////////////////////////////////////////////
'// Connect a drive with credential
function ConnectDrive2(Drive,Path,Description,User,Password)
 On Error Resume Next
 Dim objNetwork,oScriptShell
 Set objNetwork=WScript.CreateObject("WScript.Network")
 Set oScriptShell=CreateObject("WScript.Shell")
 Set oShell=CreateObject("Shell.Application")  
 err.number=0
 If User="" Then
    objNetwork.MapNetworkDrive Drive,Path
    Else
    objNetwork.MapNetworkDrive Drive,Path,False,User,Password
    End If
 If err.number<>0 Then
  oScriptShell.Popup "Connexion lecteur " & Drive & " (" & Path & ")" & VbCrLf & "Description=" & err.Description & VbCrLf & "Code=" & err.Number,5,"Erreur",64
 Else  
  oShell.NameSpace(Drive).Self.Name=Description
 End If
end function 

Cdt.

Le support

Connexion ou Créer un compte pour participer à la conversation.

Dernière édition: par Admin KoXo.

Connecter un lecteur en fonction de l'ordinateur il y a 2 ans 11 mois #1288

si on veux l'appliquer a plusieurs salle exemple cdi salleXXX doit on faire 2 lignes ou peux t'on faire

If ComputerNameBeginsWith("CDI,SALLEXXX") The


Merci pour ce script

Connexion ou Créer un compte pour participer à la conversation.

Connecter un lecteur en fonction de l'ordinateur il y a 2 ans 11 mois #1289

Bonjour,

La fonction "ComputerNameBeginsWith" n'éclate pas la chaine passée, donc ce n'est pas bon.

Il faut soit refaire la fonction pour qu'elle gère plusieurs début de noms, soit recopier/coller les trois lignes plusieurs fois ou soit utiliser un opérateur logique "OU".

exemple :
If ComputerNameBeginsWith("PC") Or ComputerNameBeginsWith("F01") Then
    ConnectDrive2 "X:","\\MyServer\MyShare","Description de ma ressource","utilisateur","motdepasse"
   End If
Cdt

Le support
Les utilisateur(s) suivant ont remercié: Olivier HUMBERT

Connexion ou Créer un compte pour participer à la conversation.

  • Page :
  • 1
Temps de génération de la page : 0.320 secondes